archpackaging

PKGBUILD (1112B) - View raw

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36


pkgbase=gruvbox-theme-git
pkgname=('gruvbox-icon-theme' 'gruvbox-gtk-theme')
pkgver=r102.578cd220
pkgrel=1
pkgdesc='A GTK theme based on the Gruvbox colour palette.'
arch=('any')
url='https://github.com/Fausto-Korpsvart/Gruvbox-GTK-Theme'
license=('GPL3')
depends=('gtk-engine-murrine')
makedepends=('git' 'sassc')
source=("$pkgbase"::'git+https://github.com/Fausto-Korpsvart/Gruvbox-GTK-Theme')
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$pkgbase"
  if git describe --long --tags >/dev/null 2>&1; then
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
  else
    printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git describe --always)"
  fi
}

package_gruvbox-icon-theme() {
  cd "$srcdir/$pkgbase"
  sed -i icons/*/index.theme -e 's/oomox-//'
  mkdir -p "$pkgdir/usr/share/icons"
  cp -r icons/Gruvbox-Dark "$pkgdir/usr/share/icons/"
  cp -r icons/Gruvbox-Light "$pkgdir/usr/share/icons/"
}

package_gruvbox-gtk-theme() {
  cd "$srcdir/$pkgbase/themes"
  ./build.sh
  mkdir -p "$pkgdir/usr/share/themes"
  ./install.sh --tweaks medium --dest "$pkgdir/usr/share/themes" --theme all
}