archpackaging

PKGBUILD (1530B) - View raw

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50


pkgname=xdg-desktop-portal-termfilechooser
pkgver=v1.2.1.r6.g8697bab
pkgrel=1
pkgdesc='xdg-desktop-portal backend for your favorite terminal file chooser (hunkyburrito fork)'
url="https://github.com/hunkyburrito/xdg-desktop-portal-termfilechooser"
arch=('x86_64')
license=('MIT')
provides=('xdg-desktop-portal-impl')
depends=('xdg-desktop-portal' 'libinih')
makedepends=('meson' 'scdoc' 'git')
optdepends=(
    'kitty: default terminal for launching wrappers'
    'lf: wrapper included'
    'nnn: wrapper included'
    'ranger: wrapper included'
    'vifm: wrapper included'
    'yazi: wrapper included'
)
source=(
    "${pkgname}::git+$url.git"
)
sha512sums=('SKIP')
conflicts=(xdg-desktop-portal-termfilechooser-hunkyburrito xdg-desktop-portal-termfilechooser-git xdg-desktop-portal-termfilechooser-boydaihungst-git xdg-desktop-portal-termfilechooser-nosystemd-git)

prepare() {
    cd "${pkgname}"
    # either it wont work on mango
    sed -i 's/UseIn=/UseIn=mango;/' termfilechooser.portal
}

pkgver () {
    cd "${pkgname}"
    (
         set -o pipefail
         git describe --long --tags --abbrev=7 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
            printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    )
}

build() {
    cd "${pkgname}"
    arch-meson -Dsd-bus-provider=libelogind -Dsystemd=disabled build
    ninja -C build
}

package() {
    cd "${pkgname}"
    DESTDIR="${pkgdir}" ninja -C build install
    install -Dm644 -t "$pkgdir/usr/share/licenses/${pkgname}" LICENSE
}